Initial put

quickstart/101-container-instance-image-registry-credentials/README.md

@@ -0,0 +1,26 @@
+# Azure Container Group
+
+This template deploys an Azure Container Group with two containers.
+
+## Terraform resource types
+
+- [random_pet](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/pet)
+- [azurerm_resource_group](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/resource_group)
+- [random_string](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/string)
+- [azurerm_container_group](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/container_group)
+
+## Variables
+
+| Name | Description | Default value |
+|-|-|-|
+| `resource_group_name_prefix` | Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription. | rg |
+| `resource_group_location` | Location of the resource group. | eastus |
+| `container_group_name` | Name of the container group resource. | "" |
+| `image_registry_credential_1_server` | Server name for the first image registry credential. | "" |
+| `image_registry_credential_1_username` | Username for the first image registry credential. | "" |
+| `image_registry_credential_1_password` | Password for the first image registry credential. | "" |
+| `image_registry_credential_2_server` | Server name for the second image registry credential. | "" |
+| `image_registry_credential_2_username` | Username for the second image registry credential. | "" |
+| `image_registry_credential_2_password` | Password for the second image registry credential. | "" |
+
+## Example

quickstart/101-container-instance-image-registry-credentials/main.tf

@@ -0,0 +1,59 @@
+resource "random_pet" "rg_name" {
+  prefix = var.resource_group_name_prefix
+}
+
+resource "azurerm_resource_group" "rg" {
+  location = var.resource_group_location
+  name     = random_pet.rg_name.id
+}
+
+resource "random_string" "azurerm_container_group_name" {
+  length  = 13
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_container_group" "example" {
+  name                = coalesce(var.container_group_name, "cg-${random_string.azurerm_container_group_name.result}")
+  resource_group_name = azurerm_resource_group.rg.name
+  location            = azurerm_resource_group.rg.location
+  ip_address_type     = "Public"
+  os_type             = "Linux"
+
+  image_registry_credential {
+    server   = var.image_registry_credential_1_server
+    username = var.image_registry_credential_1_username
+    password = var.image_registry_credential_1_password
+  }
+
+  image_registry_credential {
+    server   = var.image_registry_credential_2_server
+    username = var.image_registry_credential_2_username
+    password = var.image_registry_credential_2_password
+  }
+
+  container {
+    name   = "hw"
+    image  = "mcr.microsoft.com/azuredocs/aci-helloworld:latest"
+    cpu    = "0.5"
+    memory = "1.5"
+
+    ports {
+      port     = 80
+      protocol = "TCP"
+    }
+  }
+
+  container {
+    name   = "sidecar"
+    image  = "mcr.microsoft.com/azuredocs/aci-tutorial-sidecar"
+    cpu    = "0.5"
+    memory = "1.5"
+  }
+
+  tags = {
+    environment = "testing"
+  }
+}

quickstart/101-container-instance-image-registry-credentials/outputs.tf

@@ -0,0 +1,31 @@
+output "resource_group_name" {
+  value = azurerm_resource_group.rg.name
+}
+
+output "container_group_name" {
+  value = azurerm_container_group.example.name
+}
+
+output "container_group_ip_address" {
+  value = azurerm_container_group.example.ip_address
+}
+
+output "container_group_os_type" {
+  value = azurerm_container_group.example.os_type
+}
+
+output "container_group_image_registry_credential_1_server" {
+  value = azurerm_container_group.example.image_registry_credential[0].server
+}
+
+output "container_group_image_registry_credential_2_server" {
+  value = azurerm_container_group.example.image_registry_credential[1].server
+}
+
+output "container_group_container_1_name" {
+  value = azurerm_container_group.example.container[0].name
+}
+
+output "container_group_container_2_name" {
+  value = azurerm_container_group.example.container[1].name
+}

quickstart/101-container-instance-image-registry-credentials/providers.tf

@@ -0,0 +1,18 @@
+terraform {
+  required_version = ">=1.0"
+
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "~>3.0"
+    }
+    random = {
+      source  = "hashicorp/random"
+      version = "~>3.0"
+    }
+  }
+}
+
+provider "azurerm" {
+  features {}
+}

quickstart/101-container-instance-image-registry-credentials/variables.tf

@@ -0,0 +1,53 @@
+variable "resource_group_name_prefix" {
+  type        = string
+  default     = "rg"
+  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
+}
+
+variable "resource_group_location" {
+  type        = string
+  default     = "eastus"
+  description = "Location of the resource group."
+}
+
+variable "container_group_name" {
+  type        = string
+  description = "The name of the container group resource. The value will be randomly generated if blank."
+  default     = ""
+}
+
+variable "image_registry_credential_1_server" {
+  type        = string
+  description = "Server name for the first image registry credential."
+  default     = ""
+}
+
+variable "image_registry_credential_1_username" {
+  type        = string
+  description = "Username for the first image registry credential."
+  default     = ""
+}
+
+variable "image_registry_credential_1_password" {
+  type        = string
+  description = "Password for the first image registry credential."
+  default     = ""
+}
+
+variable "image_registry_credential_2_server" {
+  type        = string
+  description = "Server name for the second image registry credential."
+  default     = ""
+}
+
+variable "image_registry_credential_2_username" {
+  type        = string
+  description = "Username for the second image registry credential."
+  default     = ""
+}
+
+variable "image_registry_credential_2_password" {
+  type        = string
+  description = "Password for the second image registry credential."
+  default     = ""
+}